式

式は，計算や比較などの結果としてさまざまな値を表現するための手段です。式が表わす値は，DBProで扱うことができる各データ型に加えて，比較や条件判定の結果として与えられる論理値（真／偽）があります。DBProでは，各データ型に対応する単純式，比較の結果を表わす比較式，比較の結果などの論理値を演算する論理式などを総称して式と呼んでいます。論理式の一つの要素として比較式や単純式も含まれます。式は，次のような場面で使われます。

項目の初期値や計算項目の値を表現する計算式	[単価]×[数量]
集計の方法を示す集計式	#合計([金額])
置換する値を表現する置換式	#連番×10
検索や選択するレコードの条件を示す条件式	[商品]='DBPro'
入力データの正当性をチェックする検査条件	0＜[数量] AND [単価]≦1000

目次

文字列式

算術式

日付式

時刻式

年月間隔式

日時間隔式

カーソル式

キーワード式

ポインタ式

比較式

論理式と論理値

代入式

式の入力

式の要素：変数，項目参照，関数，演算子など

式の構文

文字列式

文字列式は，文字列型の値を表現します。単独の文字列定数，項目参照，関数呼出しなどであることもあれば，それらの結果を連結した文字列を意味することもあります。

形式

<文字列式>	::=	<文字列一次子>
	|	<文字列式> <連結演算子> <文字列一次子>
	|	<文字列式> <差分演算子> <文字列一次子>
<文字列一次子>	::=	<文字列定数>
	|	<項目参照>
	|	<オブジェクト参照>
	|	<変数参照>
	|	<関数呼出し>
	|	<ナル>
	|	( [ <式リスト> , ] <文字列式> )
<連結演算子>	::=	+ | ||
<差分演算子>	::=	-

例

'文字列定数も一つの文字列式'

#文字列置換('最初の引数中の A を B に置き換える','A','B')

'文字列定数と' + [項目] + 'とを連結する'

NULL || 'を含むと結果もナル'

連結演算子

• 二つの文字列を連結して一つの文字列にします。+ と書いても || と書いても意味は同じです。
• 数値とは異なり，演算子の左右の文字列は可換ではありません。つまり，
  　　'あ'+'い'
  と
  　　'い'+'あ'
  の結果は異なります。
• ナルと他の文字列との連結は，ナルになります。ただし，未入力の項目の値は常に空文字列として扱われるので，その項目と他の文字列との連結は，他の文字列がそのまま連結の値になります。

  　注：

  DBProの以前のバージョンでは未入力の文字列型項目の値をナルとして扱うか空文字列として扱うかが項目属性で指定できましたが，V4 からは常に空文字列として扱われるので，文字列型項目の値がナルになることはありません。
  項目参照以外でナルになる値と他の文字列との連結は，V4 でもナルになります。

差分演算子

• 左側の文字列から，そこに含まれる右側の文字列を取り除きます。たとえば，
  　　'東京都東中野'-'東京都'
  は
  　　'東中野'
  となります。右側の文字列に含まれる各文字を取り除くわけではありません。１文字ごとにすべて取り除きたいときは，
  　　'東京都東中野'-'東'-'京'-'都'
  のようにすれば，結果は
  　　'中野' になります。
• ナルや未入力の項目との演算は，連結演算子と同様です。

備考

• 連結，差分以外の文字列操作は，組込み関数で行ないます。文字列操作関数

算術式

算術式は，算術型の値を表現します。算術型には数値型（十進数型），整数型，実数型が含まれます。単独の算術定数，項目参照，関数呼出しなどであることもあれば，それらの結果に演算を施した結果を意味することもあります。

形式

<算術式>	::=	<算術項>
	|	<算術式> <加法演算子> <算術項>
<算術項>	::=	<算術因子>
	|	<算術項> <乗法演算子> <算術因子>
	|	<年月間隔項> <除算演算子> <年月間隔因子>
	|	<日時間隔項> <除算演算子> <日時間隔因子>
<算術因子>	::=	[ <単項演算子> ] <算術一次子>
<算術一次子>	::=	<算術定数>
	|	<項目参照>
	|	<オブジェクト参照>
	|	<変数参照>
	|	<関数呼出し>
	|	<ナル>
	|	( [ <式リスト> , ] <算術式> )
<加法演算子>	::=	+ | -
<乗法演算子>	::=	<乗算演算子>
	|	<除算演算子>
	|	<剰余演算子>
<乗算演算子>	::=	* | ×
<除算演算子>	::=	/ | ÷
<剰余演算子>	::=	MOD
<単項演算子>	::=	+ | -

例

4.3

[数量]

$COUNT+1

([英語]+[国語]+[数学])÷3

#SIN(#π/12)

算術演算子

• 算術演算子には次の種類があります。

  加法演算子	＋	加算を行なう
  	−	減算を行なう
  乗法演算子	＊ ×	乗算を行なう（乗算演算子）
  	／ ÷	除算を行なう（除算演算子）
  	MOD	左側の値を右側の値で割った余りを計算する（剰余演算子）
  単項演算子	＋	何もしない
  	−	正負の符号を反転する

• 演算を実行する前に左右の値のデータ型は合わせられます。
• 演算の結果が表現しきれないとき（絶対値のあふれ）はエラーになります。ただし，整数型どうしの演算ではエラーが検出されず，結果が不定になることがあるので注意してください。
• 整数型どうしの除算では結果も整数型になり，小数点以下は表現されずに切り捨てられます。たとえば，項目[個数]に整数 3，項目[人数]に整数 2 が入力されているとき，[個数]÷[人数] の結果は 1 になります。しかし，３÷２ は，定数が数値型に解釈されるので，1.5 になります。
• ナルと他の値との演算結果はナルになります。ただし，項目属性でナル値の扱いが“ゼロ”と指定してある項目の項目参照がナルであるときは，その項目の値がゼロであったものとして演算されます。

自動的に行なわれる型変換

• 算術式には，算術型のデータならどれでも混在させられます。つまり，数値型（十進数型），整数型および実数型のデータを混在させられます。
• データ型が異なる二つの値に対して演算しようとすると，どちらか一方のデータ型に合わせたうえで演算が実行されます。このときに合わせられるデータ型は，二つのデータ型のうち次の順番で右側にあるデータ型の方になります。
  
  　　整数型　→　数値型（十進数型）　→　実数型
  
  たとえば，数値型と実数型との演算は実数型で，整数型と実数型との演算も実数型で行なわれます。
• 式中に書かれている算術定数は，数値型（十進数型）に解釈されます。そのとき，算術定数が表現する数値の絶対値が大きくて解釈しきれないときは，実数型で解釈します。このようにして解釈された算術定数が演算に使われるときは，上記の方法で要求されているデータ型に合わせられます。

  10	→ 数値型
  3000000000.0	→ 数値型
  127E200	→ 実数型

• 式を評価（演算）した結果が，最終的に項目値としてレコードに格納されるときは，強制的にその項目のデータ型に変換されます。小数点以下が存在する値を整数型の項目に格納しようとすると，小数点以下が切り捨てられます。格納しようとする値が項目のデータ型で表現しきれないときはエラーになります。

日付式

DBProでは，日付，時刻，年数，時間数などを操作・表現するための式が用意されています。そのうちで，日付式は日付型の値を表現します。

形式

<日付式>	::=	<日付一次子>
	|	<日付式> <加法演算子> <年月間隔式>
	|	<日付式> <加法演算子> <日時間隔式>
<日付一次子>	::=	<日付定数>
	|	<項目参照>
	|	<オブジェクト参照>
	|	<変数参照>
	|	<関数呼出し>
	|	<ナル>
	|	( [ <式リスト> , ] <日付式> )
<加法演算子>	::=	+ | -

例

DATE'1992-12-31'
[誕生日]	（ただし，項目 [誕生日] が日付型とする）
日付'.'+日時間隔'100日'	（今日から 100 日後の日付を表わす）

日付を求める演算

• 日付型の値に年月間隔または日時間隔の値を加えたり引いたりすると日付型の結果が得られます。
• 日付型どうしの減算は年月間隔型になるので，日付式ではなく年月間隔式になります。
• 上記以外のデータ型を日付型に組み合わせて演算することはできません。

時刻式

DBProでは，日付，時刻，年数，時間数などを操作・表現するための式が用意されています。そのうち，時刻式は時刻型の値を表現します。

形式

<時刻式>	::=	<時刻一次子>
	|	<時刻式> <加法演算子> <日時間隔式>
<時刻一次子>	::=	<時刻定数>
	|	<項目参照>
	|	<オブジェクト参照>
	|	<変数参照>
	|	<関数呼出し>
	|	<ナル>
	|	( [ <式リスト> , ] <時刻式> )
<加法演算子>	::=	+ | -

例

TIME'12:30:00'
[出社時刻]	（ただし，項目 [出社時刻] が時刻型とする）
時刻'.'+日時間隔'1000秒'	（今から 1000 秒後の時刻）

時刻を求める演算

• 時刻型の値に日時間隔の値を加えたり引いたりすると時刻型の結果が得られます。
• 時刻型どうしの減算は日時間隔型になるので，時刻式ではなく日時間隔式です。
• 上記以外のデータ型を時刻型に組み合わせて演算することはできません。

年月間隔式

DBProでは，日付，時刻，年数，時間数などを操作・表現するための式が用意されています。そのうち，年月間隔式は年月間隔型の値を表現します。年齢計算などに便利です。

形式

<年月間隔式>	::=	<年月間隔項>
	|	<年月間隔式> <加法演算子> <年月間隔項>
	|	<日付式> <時間隔演算子> <日付式>
<年月間隔項>	::=	<年月間隔因子>
	|	<年月間隔項> <乗法演算子> <算術因子>
	|	<年月間隔項> <剰余演算子> <年月間隔因子>
	|	<年月間隔項> <剰余演算子> <算術因子>
<年月間隔因子>	::=	[ <単項演算子> ] <年月間隔一次子>
<年月間隔一次子>	::=	<年月間隔定数>
	|	<項目参照>
	|	<オブジェクト参照>
	|	<変数参照>
	|	<関数呼出し>
	|	<ナル>
	|	( [ <式リスト> , ] <年月間隔式> )
<加法演算子>	::=	+ | -
<乗法演算子>	::=	<乗算演算子>
	|	<除算演算子>
	|	<剰余演算子>
<乗算演算子>	::=	* | ×
<除算演算子>	::=	/ | ÷
<剰余演算子>	::=	MOD
<単項演算子>	::=	+ | -
<時間隔演算子>	::=	-

例

年月間隔'300年'
日付'.'-[誕生日]	（今日現在の満年齢）

年月間隔を求める演算

• 年月間隔式で表現できる演算は次の組合わせです。これ以外の組合わせの演算では，年月間隔型の結果は得られません。

  年月間隔どうしの加減算	YMINTERVAL'10年'+YMINTERVAL'100ヵ月'
  年月間隔どうしの剰余算	年月間隔'100年' MOD 年月間隔'8ヵ月'
  年月間隔と数値の乗除算	年月間隔'5年'×21
  日付から日付の減算	日付'.'-日付'1945年8月15日'

• 年月間隔と数値の剰余算では，結果は月単位で得られます。
• 年月間隔どうしの除算も可能ですが，結果は数値型になるので，算術式として扱われます。

日時間隔式

DBProでは，日付，時刻，年数，時間数などを操作・表現するための式が用意されています。そのうち，日時間隔式は日時間隔型の値を表現します。

形式

<日時間隔式>	::=	<日時間隔項>
	|	<日時間隔式> <加法演算子> <日時間隔項>
	|	<時刻式> <時間隔演算子> <時刻式>
<日時間隔項>	::=	<日時間隔因子>
	|	<日時間隔項> <乗法演算子> <算術因子>
	|	<日時間隔項> <剰余演算子> <日時間因子>
	|	<日時間隔項> <剰余演算子> <算術因子>
<日時間隔因子>	::=	[ <単項演算子> ] <日時間隔一次子>
<日時間隔一次子>	::=	<日時間隔定数>
	|	<項目参照>
	|	<オブジェクト参照>
	|	<変数参照>
	|	<関数呼出し>
	|	<ナル>
	|	( [ <式リスト> , ] <日時間隔式> )
<加法演算子>	::=	+ | -
<乗法演算子>	::=	<乗算演算子>
	|	<除算演算子>
	|	<剰余演算子>
<乗算演算子>	::=	* | ×
<除算演算子>	::=	/ | ÷
<剰余演算子>	::=	MOD
<単項演算子>	::=	+ | -
<時間隔演算子>	::=	-

例

日時間隔'10日と5時間32分40秒'
時刻'.'-[開始時刻]	（開始時刻からの経過時間）

日時間隔を求める演算

• 日時間隔式で表現できる演算は次の組合わせです。これ以外の組合わせの演算では，日時間隔型の結果は得られません。

  日時間隔どうしの加減算	[作業時間A]+[作業時間B]+[作業時間C]
  日時間隔どうしの剰余算	日時間隔'19時間' MOD 日時間隔'1時間25分'
  日時間隔と数値の乗除算	[単位時間]×[個数]÷[人数]
  時刻から時刻の減算	時刻'.'-[始業時刻]

• 日時間隔と数値の剰余算では，結果は秒単位で得られます。
• 日時間隔どうしの除算も可能ですが，結果は数値型になるので，算術式として扱われます。

カーソル式

カーソル式はカーソルを扱う式で，DPL中でだけ使用できます。

形式

<カーソル式>	::=	<カーソル一次子>
<カーソル一次子>	::=	<カーソル名>
	|	<変数参照>
	|	<関数呼出し>
	|	<ナル>
	|	( [ <式リスト> , ] <カーソル式> )

解説

• カーソルを直接扱う演算子はありませんが，NULL との比較のみが直接行なえます。つまり，#ナルか(@X) の代わりに @X = NULL と書くことができます。#ナルか
• カーソルどうしの比較 @X = @Y はできません。

ポインタ式

ポインタ型の値はメモリ中を指すアドレスです。

形式

<ポインタ式>	::=	<ポインタ項>
	|	<ポインタ式> <加法演算子> <算術項>
	|	<ポインタ式> <減算演算子> <算術項>
	|	<ポインタ式> <減算演算子> <ポインタ項>
<ポインタ項>	::=	<変数参照>
	|	<関数呼出し>
	|	<ナル>

解説

• ポインタと数値の演算の結果はポインタ型となります。ポインタとポインタの減算は数値となります。

キーワード式

キーワード型の値は，主にDPLのコマンドステートメントのパラメータに利用されます。

形式

<キーワード式>	::=	<キーワード定数>
	|	<変数参照>
	|	<関数呼出し>
	|	<ナル>

比較式

比較式は，二つまたは三つの値を比較して大小関係，前後関係，等値かどうかを判定し，結果として真または偽の値を返します。比較式は，レコードの検索や選択，データの正当性のチェックなどで頻繁に使われます。

形式

<比較式>	::=	<文字列比較式>
	|	<算術比較式>
	|	<日付比較式>
	|	<時刻比較式>
	|	<年月間隔比較式>
	|	<日時間隔比較式>
	|	<ポインタ比較式>
	|	<キーワード比較式>
<文字列比較式>	::=	<文字列式> <文字列比較演算子> <文字列式> [ <文字列比較演算子> <文字列式> ]
<算術比較式>	::=	<算術式> <算術比較演算子> <算術式> [ <算術比較演算子> <算術式> ]
<日付比較式>	::=	<日付式> <日付比較演算子> <日付式> [ <日付比較演算子> <日付式> ]
<時刻比較式>	::=	<時刻式> <時刻比較演算子> <時刻式> [ <時刻比較演算子> <時刻式> ]
<年月間隔比較式>	::=	<年月間隔式> <年月間隔比較演算子> <年月間隔式> [ <年月間隔比較演算子> <年月間隔式> ]
<日時間隔比較式>	::=	<日時間隔式> <日時間隔比較演算子> <日時間隔式> [ <日時間隔比較演算子> <日時間隔式> ]
<ポインタ比較式>	::=	<ポインタ式> <ポインタ比較演算子> <ポインタ式> [ <ポインタ比較演算子> <ポインタ式> ]
<キーワード比較式>	::=	<キーワード式> <等値比較演算子> <キーワード式>
<文字列比較演算子>	::=	<大小比較演算子>
	|	<辞書順比較演算子>
	|	<基本つづり比較演算子>
<等値比較演算子>	::=	= | <> | >< | ≠
<大小比較演算子>	::=	<等値比較演算子>
	|	< | > | <= | =< | ≦ | >= | => | ≧
<辞書順比較演算子>	::=	<< | >> | <<= | =<< | ≦≦ | >>= | =>> | ≧≧
<基本つづり比較演算子>	::=	<=> | ≒
<算術比較演算子>	::=	<大小比較演算子>
<日付比較演算子>	::=	<大小比較演算子>
<時刻比較演算子>	::=	<大小比較演算子>
<年月間隔比較演算子>	::=	<大小比較演算子>
<日時間隔比較演算子>	::=	<大小比較演算子>
<ポインタ比較演算子>	::=	<大小比較演算子>

比較対象のデータ型

• 算術比較式を除けば，異なるデータ型どうしの比較はできません。算術比較式は三つの数値に関するデータ型どうしの比較ができます。

  データ型	説明	例
  文字列比較式	文字列どうしの比較をします。次の３通りの比較ができます。 　文字符号としての大小比較 　辞書順における前後関係判定 　基本つづりの等値を判定する基本つづり比較	[性別]＝'女' 'あ'≦≦[よみ]＜＜'か'
  算術比較式	数値どうしの比較をします。数値型（十進数型），整数型，実数型が混在して構いません。	60=<[達成率]
  日付比較式	日付どうしの前後関係を判定します。	[誕生日]＜日付'昭和20年8月15日'
  時刻比較式	時刻どうしの前後関係を判定します。	[入力時刻]＞TIME'12:00:00'
  年月間隔比較式	年月間隔の長短を比較します。	YMINTERVAL'60年'≧#年齢([誕生日])≧YMINTERVAL'20年'
  日時間隔比較式	日時間隔の長短を比較します。	[処理時間]＞DTINTERVAL'1時間'

大小比較演算子

• 大小比較演算子は，すべてのデータ型の値に適用できます。
• 文字列型の場合は文字符号（文字列定数）としての大小関係が比較されます。改行はどんな文字よりも小さな値になります。
• 日付型および時刻型の場合は，時間的に後の方の日付，時刻を大きいといいます。
• 大小比較演算子には次の種類があります。

  等号	=	左右が等しければ真，異なれば偽
  不等号	<>　><　≠	左右が異なれば真，等しければ偽
  未満	<	左辺が小さいか前のとき真，そうでなければ偽
  超	>	左辺が大きいか後のとき真，そうでなければ偽
  以下	<=　=<　≦	左辺が小さいか前か等しいとき真，そうでなければ偽
  以上	>=　=>　≧	左辺が大きいか後か等しいとき真，そうでなければ偽

辞書順比較演算子

• 辞書順比較では，日本語なら五十音順，英語ならＡＢＣ順で，多くの辞書などに並べられている順序で文字列を比較します。
• 文字列を通常の大小比較したときは，文字符号で比較されるので全角（漢字符号系文字）の文字列と半角（８単位符号系文字）の文字列，および英字の大文字と小文字は，それぞれが別々のグループに並べられます。これをＡは全角も半角も大文字も小文字も同じグループとして扱い，ＢのグループよりＡのグループの方を先に並べるのが辞書順です。辞書順比較
• 辞書順比較演算子には次の種類があります。

  正順	<<	左辺が前のときに真，そうでなければ偽
  逆順	>>	左辺が後のときに真，そうでなければ偽
  以前	<<=　=<<　≦≦	左辺が前か等しいときに真，そうでなければ偽
  以後	>>=　=>>　≧≧	左辺が後か等しいときに真，そうでなければ偽

基本つづり比較演算子

• 基本つづり比較は，英字，仮名文字，記号などの文字列について，次のような違いをは無視した文字列（基本つづりと呼びます）について比較し，それによって，似通った文字列は等しいものと判定するものです。

  平仮名／片仮名

  清音／濁音／半濁音／拗音／撥音／促音

  全角／半角

  大文字／小文字

  空白文字の有無

• 基本つづり比較演算子は次のものだけです。

  類似

  <=>　≒

  基本つづりが等しいとき真，そうでなければ偽

• 基本つづり比較では，たとえば，'いしゃ' と 'いしや'，'じしん' と 'しじん' などは同じだと判定されます。英大文字と英小文字も区別されないので，単純に 'FILE' と 'file' を同一視したいような比較にも，基本つづり比較を利用することができます。
• 基本つづり比較演算子で順序関係を判定することはできません。組込み関数の #基本つづり比較 で順序関係を判定できます。

注意

• 原則として，ナルとなんらかの値を比較すると結果は常にナルであり，ナルは論理値としては偽と解釈されるので，比較式の結果としては偽となります。ただし，次のように定数 NULL との等値比較式だけは例外で，それぞれ右に示した式に解釈されます。#ISNULL，#ISNOTNULL

  <式> = NULL	→ #ISNULL(<式>)
  <式> <> NULL	→ #ISNOTNULL(<式>)

  したがって，

  $X := NULL

  <式1> = $X

  としたときの比較式の結果（常にナル）とは異なるので注意してください。データ型と定数：ナル値
• 項目属性[ナル値の扱い]に“ゼロ”が指定してある項目の値がナルであるときは，その項目の値がゼロであるとして比較が行なわれます。項目属性ダイアログ
• 文字列型の項目が未入力の場合，その値は空文字列として扱われるため，常にナルになることはありません。空文字列との比較の結果が得られます。
• カーソルどうしの比較はできません。

論理式と論理値

論理式は，比較式などによる条件判定を組み合わせて，二つ以上の条件を同時に満たす（論理積），どれか一つの条件を満たす（論理和）などといった論理演算を表現します。論理式は，レコードを探すときの検索条件や選択条件，入力データの正当性をチェックする検査条件などで使います。論理式の基本要素は，関数呼出しなどの単純式および比較式です。

論理式の形式

<論理式>	::=	<論理項>
	|	<論理式> OR <論理項>
<論理項>	::=	<論理因子>
	|	<論理項> AND <論理因子>
<論理因子>	::=	[ NOT ] <論理一次子>
<論理一次子>	::=	<単純式>
	|	<比較式>
	|	( <式リスト> )

例

[個数]>0	（ [個数]が１以上）
[県]='大阪'OR[県]='兵庫'OR[県]='京都'	（ [県]が大阪か兵庫か京都）
#ISNULL([役職]) AND [給与]>250000	（ [役職]がなくて[給与]が 250000 以上）

論理演算子

• 論理演算子には次の種類があります。

  論理和	OR	左が真なら真，そうでなくて右が真なら真，そうでなければ偽
  論理積	AND	左が偽なら偽，そうでなくて右が偽なら偽，そうでなければ真
  論理否定	NOT	一次子の値が真なら偽，偽なら真

論理値について

• DBProには論理型というデータ型が存在しないので，論理定数というものがありません。論理式において特定の論理値（真／偽）を表現するときは，他のデータ型の定数によって次のように代用します。

  文字列定数	空文字列 '' のとき偽，それ以外は真
  算術定数	ゼロのとき偽，それ以外は真
  日付定数	常に真
  時刻定数	午前0時0分0秒のとき偽，それ以外は真
  年月間隔／日時間隔定数	ゼロのとき偽，それ以外は真
  カーソル	未使用状態のとき偽，それ以外は真
  キーワード	常に真
  ポインタ	ゼロのとき偽，それ以外は真
  ナル	常に偽

• 論理式中の式や比較式の値も論理値としては上記のように解釈されます。

代入式

代入式は，代入演算子を用いて，左辺に右辺の値を設定するための式です。

形式

<代入式>

::=

<左辺> := <式>

例

[数量] := 100

$NAME := [名前]+'様'

$X := $Y := NULL

解説

• 代入式は，[表操作]-[置換]コマンドの置換式，あるいは DPL の代入ステートメントなどととして記述します。また，DPL中に右辺の式が書けるような場所には多くの場合，代入式も書けます。
• 左辺には項目名，変数名，カーソル名を指定します。右辺には設定したい値を示す式を書きます。
• 代入演算子は := だけです。
• 代入式の値は，右辺の式の値と同じになります。

式の入力

式入力ダイアログを使うと，式の構成要素を簡単に入力することができます。

• さまざまなダイアログで，式を入力するエディットボックスには [...]ボタンが付属しています。このボタンを押すと，式入力ダイアログが開きます。式入力ダイアログで式を入力した後，[OK]ボタンを押すと，式入力ダイアログで入力した文字列が最初のエディットボックスの文字カーソルの位置に入力されます。
• 表定義ウィンドウ，ビュー定義ウィンドウ，DPL作成ウィンドウでは，[編集]-[入力補助]-[式入力]で式入力ダイアログを開くことができます。やはり，文字カーソルの位置に式入力ダイアログで入力した文字列が入力されます。
• DBPro V3 でダイアログに直接表示されていた [項目名一覧]，[関数一覧]，[演算子一覧] は，V4 では廃止されました。式入力ダイアログを利用してください。